■環境構築
1.http://weblogs.macromedia.com/as_libraries/zips/flexunit.zipからダウンロードした
flexunit.zipを解凍し、適当な所に配置する。
2.Flexアプリケーションで『FlexUnitSample』プロジェクトを作成。
3.プロジェクトにライブラリパスに『glexunit.swc』を追加する。
※2で適当な場所に保存してあるのでその場所を参照する。
■クラス作成
1.『FlexUnitSample』プロジェクトTemperatureConverter.asを追加する。
package {
public class TemperatureConverter {
public static function toFahrenheit(celsius:Number):Number {
return (9 / 5) * celsius + 32;
}
public static function toCelsius(fahrenheit:Number):Number {
return (5 / 9) * (fahrenheit - 32);
}
}
}
2.『FlexUnitSample』プロジェクトTemperatureConverter.asを追加する。
package {
import flexunit.framework.TestCase;
import flexunit.framework.TestSuite;
public class TemperatureConverterTest extends TestCase {
public function TemperatureConverterTest(methodName:String) {
super(methodName);
}
public static function suite():TestSuite {
var suite:TestSuite = new TestSuite();
suite.addTest(new
TemperatureConverterTest("testToFahrenheit"));
suite.addTest(new
TemperatureConverterTest("testToCelsius"));
return suite;
}
public function testToFahrenheit():void {
var celsius:Number = 100;
var fahrenheit:Number =
TemperatureConverter.toFahrenheit(celsius);
assertEquals("Expecting 212 fahrenheit", 212, fahrenheit);
celsius = 0;
fahrenheit = TemperatureConverter.toFahrenheit(celsius);
assertEquals("Expecting 32 fahrenheit", 32, fahrenheit);
}
public function testToCelsius():void {
var fahrenheit:Number = 212;
var celsius:Number =
TemperatureConverter.toCelsius(fahrenheit);
assertEquals("Expecting 100 celsius", 100, celsius);
fahrenheit = 32;
celsius = TemperatureConverter.toCelsius(fahrenheit);
assertEquals("Expecting 0 celsius", 0, celsius);
}
}
}
3.『FlexUnitSample』プロジェクトsample_test.mxmlを追加する。
<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns="*"
xmlns:flexunit="flexunit.flexui.*"
creationComplete="onCreationComplete()">
<mx:Script>
<![CDATA[
import flexunit.framework.TestSuite;
private function onCreationComplete():void {
testRunner.test = createSuite();
testRunner.startTest();
}
private function createSuite():TestSuite {
var suite:TestSuite = new TestSuite();
suite.addTest(TemperatureConverterTest.suite());
return suite;
}
]]>
</mx:Script>
<flexunit:TestRunnerBase id="testRunner" width="100%" height="100%"
/>
</mx:Application>
■テスト実行
1.sample_test.mxmlをデフォルトアプリケーションに設定して実行する。
2.テスト結果が表示されることを確認する。
以上
最終更新:2007年01月26日 12:46