トップページ > Unity(Unity3D) > 内蔵シェーダのソースコード > Mobile > Bumped Specular (1 Directional Light)

「トップページ/Unity(Unity3D)/内蔵シェーダのソースコード/Mobile/Bumped Specular (1 Directional Light)」の編集履歴（バックアップ）一覧はこちら

「トップページ/Unity(Unity3D)/内蔵シェーダのソースコード/Mobile/Bumped Specular (1 Directional Light)」(2013/02/02 (土) 14:43:50) の最新版変更点

追加された行は緑色になります。

削除された行は赤色になります。

 // Simplified Bumped Specular shader. Differences from regular Bumped Specular one:
 // - no Main Color nor Specular Color
 // - specular lighting directions are approximated per vertex
 // - writes zero to alpha channel
 // - Normalmap uses Tiling/Offset of the Base texture
 // - no Deferred Lighting support
 // - no Lightmap support
 // - supports ONLY 1 directional light. Other lights are completely ignored.
 
 Shader "Mobile/Bumped Specular (1 Directional Light)" {
 Properties {
 	_Shininess ("Shininess", Range (0.03, 1)) = 0.078125
 	_MainTex ("Base (RGB) Gloss (A)", 2D) = "white" {}
 	_BumpMap ("Normalmap", 2D) = "bump" {}
 }
 SubShader { 
 	Tags { "RenderType"="Opaque" }
 	LOD 250
 	
 CGPROGRAM
 #pragma surface surf MobileBlinnPhong exclude_path:prepass nolightmap noforwardadd halfasview novertexlights
 
 inline fixed4 LightingMobileBlinnPhong (SurfaceOutput s, fixed3 lightDir, fixed3 halfDir, fixed atten)
 {
 	fixed diff = max (0, dot (s.Normal, lightDir));
 	fixed nh = max (0, dot (s.Normal, halfDir));
 	fixed spec = pow (nh, s.Specular*128) * s.Gloss;
 	
 	fixed4 c;
 	c.rgb = (s.Albedo * _LightColor0.rgb * diff + _LightColor0.rgb * spec) * (atten*2);
 	c.a = 0.0;
 	return c;
 }
 
 sampler2D _MainTex;
 sampler2D _BumpMap;
 half _Shininess;
 
 struct Input {
 	float2 uv_MainTex;
 };
 
 void surf (Input IN, inout SurfaceOutput o) {
 	fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
 	o.Albedo = tex.rgb;
 	o.Gloss = tex.a;
 	o.Alpha = tex.a;
 	o.Specular = _Shininess;
 	o.Normal = UnpackNormal (tex2D(_BumpMap, IN.uv_MainTex));
 }
 ENDCG
 }
 
 FallBack "Mobile/VertexLit"
 }

#amazon2(728x90)