表作成支援ツール - comiked

表作成支援ツール

概要?

• スプレッドシートで作成した表をアットウィキで使用できる書式に変換するツールです。
• 表をいちいち@wiki向けに加工するのが面倒な方向けの機能です。
• 簡単なエクセルの使い方に成れている方であれば使用可能です。

例えば…

エクセルで作ったこんな表を

#	A	B
1	aaa	bbb
2	ccc	ddd

こんな感じの書式に変換できます。

• |BOTTOM:SIZE(11):BGCOLOR(#BDD7EE):#|BOTTOM:SIZE(11):BGCOLOR(#BDD7EE):A|BOTTOM:SIZE(11):BGCOLOR(#BDD7EE):B|h
• |BOTTOM:SIZE(11):1|BOTTOM:SIZE(11):aaa|BOTTOM:SIZE(11):bbb|
• |BOTTOM:SIZE(11):2|BOTTOM:SIZE(11):ccc|BOTTOM:SIZE(11):ddd|

使い方

① 作成したい表をスプレッドシート上で「選択状態」にする
② alt + F8等で下記のマクロ「TableToAtwikiText()」を実行してください。
③ アットウィキ記法でのテーブル書式がクリップボードにコピーされます。

スクリプト

VBAのスクリプトは以下に置いておきます。興味のある方はご自身のエクセル環境等でお試しください。

...

Sub TableToAtwikiText()
    Dim row As Range
    Dim cell As Range
    Dim val As Variant
    Dim vAlign As String
    Dim hAlign As String
    Dim font As String
    Dim str As String
    Dim outputString As String
    Dim hflg As Boolean
    Dim marge_left_col As Integer
    Dim marge_col_size As Integer
 
    outputString = ""
    hflg = True
 
    For Each row In Selection.Rows
        outputString = outputString & "|"
        For Each cell In row.Cells
            val = cell.Value
            vAlign = GetVerticalAlignment(cell)
            hAlign = GetHorizontalAlignment(cell)
            font = GetFont(cell)
 
            ' 結合されたセル
            If cell.MergeCells Then
                ' 最上端の行
                If cell.row = cell.MergeArea.Item(1).row Then
                    marge_left_col = cell.MergeArea.Item(1).Column
                    marge_col_size = cell.MergeArea.Columns.Count
                    ' 最右端の列
                    If cell.Column = marge_left_col + marge_col_size - 1 Then
                        str = vAlign & hAlign & font & cell.MergeArea.Item(1).Value
                    Else
                        str = ">"
                    End If
                Else
                    str = "~"
                End If
            Else
                str = vAlign & hAlign & font & val
            End If
            str = Replace(str, vbLf, "&br()")
            str = Replace(str, "|", "")
            outputString = outputString & str & "|"
        Next cell
        If hflg Then
            outputString = outputString & "h"
            hflg = False
        End If
        outputString = outputString & vbNewLine
 
    Next row
    'Debug.Print outputString
    If MsgBox("クリップボードにコピーしますか？", vbYesNo) = vbYes Then
        With CreateObject("Forms.TextBox.1")
            .MultiLine = True '複数行入力可
            .Text = outputString
            .selstart = 0
            .sellength = .textlength
            .Copy
        End With
    End If
End Sub
 
' - 縦の文字位置設定
Function GetVerticalAlignment(cell As Range) As String
    Select Case cell.VerticalAlignment
        Case xlTop
            GetVerticalAlignment = "TOP:"
        Case xlCenter
            GetVerticalAlignment = "MIDDLE:"
        Case xlBottom
            GetVerticalAlignment = "BOTTOM:"
        Case Else
            GetVerticalAlignment = ""
    End Select
End Function
 
' - 横の文字位置設定
Function GetHorizontalAlignment(cell As Range) As String
    Select Case cell.HorizontalAlignment
        Case xlRight
            GetHorizontalAlignment = "RIGHT:"
        Case xlLeft
            GetHorizontalAlignment = "LEFT:"
        Case xlCenter
            GetHorizontalAlignment = "CENTER:"
        Case Else
            GetHorizontalAlignment = ""
    End Select
End Function
 
' - フォント設定
 
Function GetFont(cell As Range) As String
    GetFont = ""
    If cell.font.Size <> 0 Then
        GetFont = GetFont & "SIZE(" & cell.font.Size & "):"
    End If
 
    If cell.font.Color <> vbBlack Then
        GetFont = GetFont & "COLOR(" & cell.font.Color & "):"
    End If
 
    Dim RGB As Variant
    RGB = Right("00000" & Hex(cell.Interior.Color), 6)
    BGR = Right(RGB, 2) & Mid(RGB, 3, 2) & Left(RGB, 2)
    If cell.Interior.Color <> vbWhite Then
        GetFont = GetFont & "BGCOLOR(#" & BGR & "):"
    End If
End Function
 
 

※注意事項

• セル内で「vb改行 "vbLf"」が使用されている場合は「br改行 "&br()"」に置換されます。
• セル内で「パイプ文字 "|"」が使用されている場合は「空白 ""」に置換されます。

気が向いたらGoogleスプレッドシート上でお試しできる場所を作ります。

現状変換可能な書式

大項目	小項目	プロパティ	アットウィキ記法	アットウィキ表示例
列表記			"|aaa|"	aaa
ヘッダー行表記			"|aaa|h"	aaa
セル内での改行			"|bbb&br()cccパ"	bbb ccc
縦方向位置	上揃え	VerticalAlignment(xlTop)	"TOP:トップ(上)"	==========トップ(上)==========
	中央揃	VerticalAlignment(xlTop)	"MIDDLE:ミドル(中)"	==========ミドル(中)==========
	下揃え	VerticalAlignment(xlBottom)	"BOTTOM:ボトム(下)"	==========ボトム(下)==========
横方向位置	左寄せ	HorizontalAlignment(xlLeft)	"LEFT:レフト(左)"	レフト(左)
	中央寄せ	HorizontalAlignment(xlCenter)	"CENTER:センター(中)"	センター(中)
	右寄せ	HorizontalAlignment(xlRight)	"RIGHT:ライト(右)"	ライト(右)
フォントサイズ	文字サイズ	font.Size	"SIZE(x):文字"	文字のサイズを20pxにする
フォントカラー	文字カラー	font.Color	"COLOR(x):文字"	青色の文字
	背景カラー	cell.Interior.Color	"BGCOLOR(x):文字"	黄色の背景色
セル結合	横方向		"|>|"	横の結合
	縦方向		"|~|"	縦の結合