Sample Program - OpenGL ES 2.0 / GLSL 1.0

A shader pair that applies diffuse and ambient lighting to a textured object.

Vertex Shader

uniform mat4 mvp_matrix;      // model-view-projection matrix
uniform mat3 normal_matrix;   // normal matrix
uniform vec3 ec_light_dir;    // light direction in eye coords
attribute vec4 a_vertex;      // vertex position
attribute vec3 a_normal;      // vertex normal
attribute vec2 a_texcoord;    // texture coordinates
varying float v_diffuse;
varying vec2 v_texcoord;
void main(void)
{
  // put vertex normal into eye coords
  vec3 ec_normal = normalize(normal_matrix * a_normal);
  // emit diffuse scale factor, texcoord, and position
  v_diffuse = max(dot(ec_light_dir, ec_normal), 0.0);
  v_texcoord = a_texcoord;
  gl_Position = mvp_matrix * a_vertex;
}
 

Fragment Shader

precision mediump float;
uniform sampler2D t_reflectance;
uniform vec4 i_ambient;
varying float v_diffuse;
varying vec2 v_texcoord;
void main (void)
{
  vec4 color = texture2D(t_reflectance, v_texcoord);
  gl_FragColor = color * (vec4(v_diffuse) + i_ambient);
}