スクリプト - ARMA 3 JPN MENTAIKO COOP SERVER @wiki

最終更新日 : 2020年08月27日

スクリプト

本ページでは、MENTAIKO COOPのミッション作成に使用されるスクリプトファイルの紹介とその解説をします。

スクリプトコマンドについては以下を参考にしてください。

• 本Wiki : スクリプトコマンド
• BI公式 : Scripting Commands Arma 3
• BI公式 : Arma 3: Functions

---

イベントスクリプト

イベントスクリプトとは、ミッションフォルダに設置するだけで、特定のタイミングで動作するスクリプトファイルです。

詳細: Event Scripts

mission.sqm

ミッションの本体
EDENで編集した内容はこのファイルに保存される。
Binarizeを解除することで直接編集も可能である。

Addonの更新などでEDENからミッションが読み込めなくなることもあるので、Binarizeは提出時のみして普段はチェックを外しておくことをオススメします。

[部分編集]

description.ext

詳細: Description.ext

ミッションの属性や定義を行うファイルです。
下手に手を加えるとMissionが動かなくなるので、テキスト以外を編集する際は上記のリンクを熟読した後に編集することをオススメします。

//------------------------------LOADING INFO------------------------------
//
	author = "作者名"; 
	onLoadName = "MC[coXX]Mission_Name";
	loadScreen = "pics\MENTAIKOLOGO.jpg";
	overviewPicture = "pics\MENTAIKOLOGO.jpg";
	onLoadMission = "<t color='#e80301'>MENTAIKO SERVER</t>";
	overviewText = "ミッションの概要(短文),最終更新日,作者名";
 
	disabledAI = 1;
	enableDebugConsole = 1;
	forceRotorLibSimulation = 2;
//
//------------------------------GAMETYPE----------------------------------
//
	class Header
	{
		gameType = Coop;
		minPlayers = 1; 
		maxPlayers = 120;
	};
//
//------------------------------RESPAWN SETTINGS--------------------------
//
	respawn = 3;
	respawndelay = 1;
	respawnTemplates[] = {"Counter","ace_spectator"};
	respawnButton = 1;
	respawnOnStart = 0;
//
//----------------------------DERETE BODY&WRECK---------------------------
//
	corpseManagerMode = 1;
	corpseLimit = 24;
	corpseRemovalMinTime = 300;
	corpseRemovalMaxTime = 600;
 
	wreckManagerMode = 1;
	wreckLimit = 6;
	wreckRemovalMinTime = 600;
	wreckRemovalMaxTime = 900;
//
//---------------------------------ENDING---------------------------------
//
	class CfgDebriefing
	{
		class End1
		{
			title = "MISSION ACCOMPLISHED";
			subtitle = "作戦成功";
			description = "";
			picture = "";
			pictureColor[] = {0,0,0,1};
		};
		class End2
		{
			title = "MISSION FAILED";
			subtitle = "作戦失敗";
			description = "";
			picture = "";
			pictureColor[] = {0,0,0,1};
		};
	};
 

[部分編集]

init.sqf

イベントスクリプトの一つ。

init.sqfはミッション開始時（ブリーフィング画面の前）に実行されます。
一番最初に実行すべきスクリプトはここで実行しましょう。

if (!isDedicated) then {waitUntil {!isNull player && isPlayer player};};
 
enableRadio false;
tawvd_disablenone = true;
CHVD_allowNoGrass = false;
enableSaving [false,false];
 
/* =============== Player Only Commands ================ */
if (hasInterface) then {
	call compile preprocessFileLineNumbers "briefing.sqf";
};
 
/* =============== Server Only Commands ================ */
if (isServer) then {
	west setFriend [independent, 1]; // 1:友好, 0:敵対, 境界:0.6
	independent setFriend [west, 1];
	east setFriend [independent, 0];
	independent setFriend [east, 0];
};
 
/* ==================== MCC Bugfix ===================== */
_EndSplashScreen = { for "_x" from 1 to 4 do { endLoadingScreen; sleep 3; }; };
[] spawn _EndSplashScreen;
 
/* ==================== End Of File ==================== */
player globalChat format ["Mission Initialisation Complete. Press CONTINUE"];
finishMissionInit;
 

[部分編集]

(補足) briefing.sqf

ブリーフィングについて

マップメニューにブリーフィングを追加します。ブリーフィングは、ミッションの背景や任務・補足事項・注意事項などをプレイヤーに伝えるために必要です。

ブリーフィングに記載すべきこと

ブリーフィングに記載すべきことは

1. （任意）ミッション背景
2. （必須）METT-TC
   • Mission (ミッションの目的)
   • Enemy (敵勢力の情報)
   • Terrain and weather (地形・気象)
   • Troops & support available (味方部隊の情報と利用可能な支援)
   • Time (時間)
   • Civilians (民間人の情報)
3. （任意）追加情報
4. （必須）システム関係
5. （任意）補足情報

ブリーフィング記述時の注意

ブリーフィングはプレイヤーにミッションの目的などの情報を伝えることが目的です。
そのためにも、いくつか注意しなければならないことがあります。

ミッションの目的は簡潔明瞭に

ブリーフィングは限られた時間で読まなければならないので、簡潔明瞭に記述つすることが望まれます。ミッションの概要説明はMETT-TCなどを活用して記載してください。

一方で、ミッション背景ついては自由に記述しても問題ありません。好きなように書いてしまいましょう。

敵の情報は正確に記述する必要はありません

不測の事態を楽しむのもCOOPの醍醐味です。

敵の人数や、兵器の詳細を事細かく記述する必要はありません。

ただし、戦車や攻撃ヘリなどの特別な装備がなければ対応できない驚異が存在する場合は、その可能性を伝えることでプレイヤーフレンドリーとなるでしょう。

順番に注意する

スクリプトコマンドの"createDiaryRecord"はbriefing.sqfの上から順に読み込まれ、新しく読み込まれたものはリスト上に追加されていきます。

つまり、briefing.sqfで記述した順番と表示される順番は逆になります。

// init.sqfに　"call compile preprocessFileLineNumbers "briefing.sqf";"　と記述して下さい
// 改行は文末に "<br />" と記述します
// 画像を張り付けるには　"<img image='フォルダパス\フォルダパス\pict.jpg' width='400' height='200'/>"
 
player createDiaryRecord
[
	"Diary",
	[
		"Editorより",	"
		捕虜をエスコートするためにはケーブルタイが必要です。<br/>
		"
	]
];
 
player createDiaryRecord
[
	"Diary",
	[
		"システム","
		【Mission End】<br/>
		全タスク達成後、自動でミッションが終了します。<br/>
		<br/>
		【Respawn】<br/>
		死亡時はベースにリスポーンします。<br/>
		乗り物はリスポーンしません。<br/>
		リスポーン後はテレポートでチームに合流してください。<br/>
		<br/>
		【Teleport】<br/>
		NATOフラッグから所属チームのリーダーのもとへテレポートすることができます。<br/>
		<br/>
		【Heal Self】<br/>
		ベースの医療テントにて自己治療できます。<br/>
		<br/>
		【Full Arsenal】<br/>
		制限Arsenalに不備があった場合は、Briefing RoomのボックスよりFull Arsenalを使用してください。
		"
	]
];
 
player createDiaryRecord
[
	"Diary",
	[
		"捕虜詳細","
		【Name】 ヘンリー・A・ジョンソン<br/>
		<img image='pics\hostage.jpg' width='256' height='256'/><br/>
		【Description】<br/>
		・32歳、男性<br/>
		・ギリシャ在中イギリス人
		"
	]
];
 
player createDiaryRecord
[
	"Diary",
	[
		"METT-TC","
		【任務(Mission)】<br/>
		1. 敵前哨基地の制圧<br/>
		2. 情報の回収<br/>
		3. 民間人の保護<br/>
		<br/>
		【敵情(Enemy)】<br/>
		CSAT　欧州派遣部隊<br/>
		勢力規模:30人程度<br/>
		武装された軽車両が確認されている<br/>
		制空権は我軍がAAFと共に確保済み<br/>
		<br/>
		【地形・気象(Terrain and weather)】<br/>
		・丘陵地帯<br/>
		<br/>
		【部隊(Troops)】<br/>
		NATO軍 先遣部隊<br/>
		攻撃ヘリコプター AH-99 Blackfoot<br/>
		<br/>
		【時刻(Time)】<br/>
		作戦開始時刻 AM 16:30<br/>
		<br/>
		【民事(Civil Consideration)】<br/>
		作戦地域周辺の民間人は避難済み。<br/>
		ただし、敵前哨基地内には捕虜が存在する。
		"
	]
];
 
player createDiaryRecord
[
	"Diary",
	[
		"作戦概要","
		【日付】<br/>
		2035/05/27<br/>
		<br/>
		【背景】<br/>
		我軍はAltis等の覇権をめぐり、AAFと共にCSATと交戦中である。
		<br/>
		【任務】<br/>
		マップ上のポイント「<marker name='object_1'>X-Ray</marker>」に敵部隊の前哨基地が確認された。<br/>
		敵の前哨基地を制圧し、敵部隊の動向を把握するための情報を確保せよ。<br/>
		<br/>
		CSATは逃げ遅れた民間人を捕虜にしている。<br/>
		民間人に危害を加えぬように注意せよ。<br/>
		<br/>
		【作戦終了条件】<br/>
		全タスク達成にて本作戦は完了とする。
		"
	]
];
 

[部分編集]

onPlayerRespawn.sqf

リスポーン時に実効するイベントスクリプト。

params ["_newUnit","_oldUnit"];
 
_newUnit addRating 20000;
_newUnit setDamage 0;
[_newUnit] call ace_medical_treatment_fnc_fullHealLocal;
 
if (_oldUnit != objNull) then {
	hideBody _oldUnit;
	sleep 4;
	deleteVehicle _oldUnit;
}; 

プレイヤーに付け加えたaddActionはリスポーン時に外れてしまうため、onPlayerRespawn.sqfにて再度付与すること。
例.

_newUnit addAction ["Action Title",{Script Cord}];

---

その他スクリプト

[部分編集]

aiSetting.sqf

AIの設定を行うスクリプト

/*
init.sqfに次を記述
if (isServer) then { call compile preprocessFileLineNumbers "aiSetting.sqf" };
*/
if (!isServer) exitWith {};
 
comment "敵陣営を設定";
private _enemies = allUnits select {side _x == EAST};
private _enemyGroups = allGroups select {side _x == EAST};
 
comment "AIのスキル設定";
{
  _x setSkill ["general",0.50];		// 基本数値(0: 最小, 1: 最大)
  _x setSkill ["aimingAccuracy",0.10];	// 射撃精度
  _x setSkill ["aimingSpeed",0.40];  	// AIMの速さ
  _x setSkill ["courage",0.80];		// 勇気
  _x setskill ["commanding",0.55];		// 情報共有の速さ正確性
  _x setskill ["aimingShake",0.35];  	// 手ブレの大きさ
  _x setskill ["spotDistance",0.80]; 	// 敵を発見できる距離
  _x setskill ["spotTime",0.60];		// 敵を見つけるまでの時間
} forEach _enemies;
 
comment "AIグループの初期設定";
{
  _x setBehaviour "SAFE";
  _x setCombatMode "YELLOW";
} forEach _enemyGroups;